Test with prepared session

[ravecat]

I want to run tests without having to run whole authentication flow. Found a forum thread discussing such functionality in wallaby

Based on the proposed solutions, organized the test case, but I can't localize the cause of the problems below (wrong cookie format or specifics of set_cookie operation?)

feature "put cookie directly", ctx do
      endpoint_opts = Application.get_env(:runa, RunaWeb.Endpoint)
      secret_key_base = Keyword.fetch!(endpoint_opts, :secret_key_base)

      conn =
        %Plug.Conn{secret_key_base: secret_key_base}
        |> Plug.Conn.put_resp_cookie("_runa_key", %{user_id: ctx.user.id},
          sign: true
        )

      resp_cookie = conn.resp_cookies["_runa_key"][:value]

      ctx.session
      |> visit("/")
      |> set_cookie("_runa_key", resp_cookie)
      |> visit("/team")
      |> assert_has(Query.css("[aria-label='Team members']"))
    end

but ran into a few problems (these are pictured), code here

1. Empty session data inside Plug.Session
   
2. Strange format of encoded cookies, tuple with timestamp instead of map

req_cookies: SFMyNTY.g2gDdAAAAAF3B3VzZXJfaWRiAAInSG4GAEA0WjSWAWIAAVGA.I4hPlHmkS2Jrz5qZgpwHv7AvGXVCqpW7Hy6oxNmCdQo
encoded_cookie_data: {%{user_id: 141128}, 1744635049024, 86400}

I have prepared a test example

git clone -b demo_e2e_set_cookie --single-branch git@github.com:ravecat/runa.git
mix setup
mix test.watch --only only

[ravecat]

Wrote helper for change Wallaby session based on desired data, I've try to generate a session cookie without a real request by manually simulating parts of the Plug pipeline. It forces the execution of any before_send hooks to finalize the response (which includes generating the cookie). Current approach is a bit closer to actual cookie generation than just put_resp_cookie

put_session.ex

 @spec put_session(Wallaby.Session.t(), atom(), term()) :: Wallaby.Session.t()
  def put_session(session, key, value) do
    endpoint_opts = Application.get_env(:runa, AppWeb.Endpoint)
    secret_key_base = Keyword.fetch!(endpoint_opts, :secret_key_base)
    session_opts = Keyword.fetch!(endpoint_opts, :session_options)
    cookie_key = Keyword.fetch!(session_opts, :key)

    conn =
      %Plug.Conn{secret_key_base: secret_key_base}
      |> Plug.Session.call(Plug.Session.init(session_opts))
      |> Plug.Conn.fetch_session()
      |> Plug.Conn.put_session(key, value)
      |> Plug.Conn.resp(:ok, "")
      |> then(fn conn ->
        Enum.reduce_while(conn.private.before_send || [], conn, fn fun, acc ->
          {:cont, fun.(acc)}
        end)
      end)

    resp_cookie = conn.resp_cookies[cookie_key][:value]

    session
    |> Wallaby.Browser.visit("/")
    |> Wallaby.Browser.set_cookie(cookie_key, resp_cookie)
  end

Helper required session options inside test environment test.exs

config :runa, AppWeb.Endpoint,
  http: [ip: {127, 0, 0, 1}, port: 4002],
  secret_key_base:
    "C3Vz504bPAE0Ik6A4nGbALDBrwNFGurw445+WHG8e7H9toKW8EfaXfhJN+K",
  session_options: [
    store: :cookie,
    key: "_awesome_test",
    signing_salt: "buKCuE47",
    same_site: "Lax"
  ],
  server: true

and minor changes endpoint.ex

  @session_options Application.compile_env(
                     :runa,
                     [AppWeb.Endpoint, :session_options],
                     store: :cookie,
                     key: "_default_key",
                     signing_salt: "buKCuE42",
                     same_site: "Lax"
                   )

Example

    feature "has ability to delete non-owner members", ctx do
      session =
        put_session(ctx.session, :user_id, ctx.user.id)
        |> visit("/team")
        |> assert_has(Query.css("[aria-label='Team members']"))

      {member, _} =
        Enum.find(ctx.members, fn {_, role} -> role.role != :owner end)

      assert_has(
        session,
        Query.css("[aria-label=\"Member #{member.name} form\"]",
          text: member.name
        )
      )
      |> click(Query.css("[aria-label=\"Delete #{member.name} from team\"]"))
      |> click(Query.css("[aria-label=\"Confirm delete contributor\"]"))
      |> visit("/team")
      |> assert_has(
        Query.css("[aria-label=\"Member #{member.name} form\"]", count: 0)
      )
    end